Dataplot Vol 1 Vol 2

# DEX <STATISITC> PLOT

Name:
DEX <statistic> PLOT
Type:
Graphics Command
Purpose:
Generates a Design of Experiment (dex) plot for a given statistic.
Description:
A dex statistic plot is a graphical method for representing a design of experiment problem. The first variable is a response variable while the remaining variables (there must be at least one) represent levels of factors. A separate subplot is drawn for each factor with the subplot for factor k centered horizontally at x = k. Each subplot has a given horizontal width (defined by the DEX WIDTH command, defaults to 0.5). For example, the subplot for factor 2 ranges from 1.75 to 2.25 on the horizontal axis. The levels of the factor are assigned an x coordinate within this range (from lowest to highest). Then within each subplot:

 Vertical axis = value of the computed statistic from the response variable (i.e., compute the statistic for all values with the same level for a given factor); Horizontal axis = value of the level of a given factor.

This plot graphically shows the following:

1. How the statistic for the response variable varies with the level of the factor.

2. How the statistic for the response variable varies between factors.

The DEX ... PLOT is most commonly used for the mean. However, you can in fact generate this plot for any statistic supported in Dataplot. The primary application of this plot is in the analysis of 2-level full or fractional designs to identify the most important factors.

Syntax:
DEX <stat> PLOT <y1> ... <y3> <x1> ... <xk>
<SUBSET/EXCEPT/FOR qualification>
where <y1> ... <y3> is a list of one to three response variables (depending on the requested statistic);
<x1> ... <xk> is a list of one to k factor variables;
<stat> is the desired statistic;
and where the <SUBSET/EXCEPT/FOR qualification> is optional.

For a list of supported statistics, enter HELP STATISTICS.

Examples:
DEX MEAN PLOT Y X1 X2
DEX MEDIAN PLOT Y X1 X2
DEX SD PLOT Y X1 X2 X3
DEX RANGE PLOT Y X1 X2 X3 X4
DEX SD PLOT Y X1 TO X3
DEX MEAN PLOT Y X1 TO X8
Note:
This plot is most typically generated for a location statistic (typically the mean or median) or a spread statistic (typically the standard deviation or range). The other statistics are rarely used.
Note:
The TO syntax is allowed for the list of factor variables (see the EXAMPLES above).
Note:
The CHARACTER and LINE settings can be used to control the appearance of the plot. The first trace is typically drawn with a blank line and some type of character set (the choice of character is a matter of user preference). The second trace draws a horizontal line at the value for the specified statistic for the entire response variable. This is typically drawn with a blank character and a solid line (some analysts may prefer a dashed or dotted line). In any event, the user must explicitly set character and line settings (they default to all lines solid and all characters blank).
Note:
By default, this plot is generated for the main effects only. If you would like to include the 2-term interaction effects, enter

SET DEX STATISTIC PLOT INTERACTION 2

To include both 2-term and 3-term interaction effects, enter

SET DEX STATISTIC PLOT INTERACTION 3

To restore the default of main effects only, enter

SET DEX STATISTIC PLOT INTERACTION NONE

When interaction terms are requested, the terms are written to file "dpst5f.dat" in the order they are generated on the plot. For example, for three factor variables where both 2-term and 3-term interactions are requested, the following will be written to dpst5f.dat

X1
X2
X3
X1*X2
X1*X3
X2*X3
X1*X2*X3
Default:
None
Synonyms:
None
Related Commands:
 LINES = Sets the type for plot lines. CHARACTER = Sets the type for plot characters PLOT = Generates a data or function plot. DEX SCATTER PLOT = Generates a dex scatter plot. DEX SIGN PLOT = Generates a dex sign plot. DEX ... PARETO PLOT = Generates a Pareto dex plot for a statistic. DEX ... YOUDEN PLOT = Generates a Youden dex plot for a statistic. DEX ... EFFECTS PLOT = Generates a dex effects plot for a statistic. DEX ... PARETO EFFECTS PLOT = = Generates a Pareto effects dex plot for a statistic. DEX ... ABSOLUTE EFFECTS PLOT = Generates an absolute effects dex plot for a statistic. DEX ... PARETO ABSOLUTE EFFECTS PLOT = Generates a Pareto absolute effects dex plot for a statistic. DEX WIDTH = Specifies the width of levels in a dex plot.
Reference:
Box, Hunter, and Hunter (1978), "Statistics for Experimenters", John Wiley.
Applications:
Design of Experiments
Implementation Date:
1989/12: Original implementation for a limited number of statistics
2002/08: List of supported statistics expanded.
2019/03: Added support for SET DEX STATISTIC PLOT INTERACTION
Program 1:
```
SKIP 25
READ SHEESLE2.DAT Y X1 X2 X3 X4
.
TIC MARK LABEL CASE ASIS
LABEL CASE ASIS
TITLE CASE ASIS
CASE ASIS
X1LABEL DISPLACEMENT 12
.
CHARACTERS X BLANK
LINES SOLID SOLID
LET NFACT = 4
XLIMITS 1 NFACT
MAJOR XTIC MARK NUMBER NFACT
MINOR XTIC MARK NUMBER 0
X1TIC OFFSET 1 1
X1TIC LABEL FORMAT ALPHA
X1TIC LABEL CONTENT Weld Plant Speed Shift
X1LABEL Factors
YLIMITS 20 28
.
MULTIPLOT CORNER COORDINATES 0 0 100 100
MULTIPLOT SCALE FACTOR 2
.
MULTIPLOT 2 2
Y1LABEL Mean Defects
DEX MEAN PLOT Y X1 TO X4
.
Y1LABEL Median Defects
DEX MEDIAN PLOT Y X1 TO X4
.
YLIMITS
Y1LABEL Standard Deviation of Defects
DEX SD PLOT Y X1 TO X4
.
Y1LABEL Range of Defects
DEX RANGE PLOT Y X1 TO X4
END OF MULTIPLOT
.
JUSTIFICATION CENTER
MOVE 50 97
TEXT DEX Statistic Plots for SHEESLE2.DAT
```
Program 2:
```
SKIP 25
READ SHEESLE2.DAT Y X1 TO X4
.
TITLE CASE ASIS
LABEL CASE ASIS
CHARACTERS X BLANK
LINES SOLID SOLID
.
.  Generate plots with interaction terms
.
.  Since we want interaction terms, code to -1 and + 1
.
LET Z1 = CODE DEX 2-LEVEL X1
LET Z2 = CODE DEX 2-LEVEL X2
LET Z3 = CODE DEX 2-LEVEL X3
.
TIC MARK OFFSET UNITS DATA
X1TIC MARK OFFSET 1 1
XLIMITS 1 7
MAJOR XTIC MARK NUMBER 7
X1TIC MARK LABEL FORMAT ALPHA
X1TIC MARK LABEL CONTENT X1 X2 X3 X1*X2 X1*X3 X2*X3 X1*X2*X3
SET DEX STATISTIC PLOT INTERACTION 3
.
Y1LABEL Mean Defective Leads per Hour
X1LABEL Factors
TITLE DEX Mean Plot with 2- and 3-Term Interactions
DEX MEAN PLOT Y Z1 Z2 Z3
```

NIST is an agency of the U.S. Commerce Department.

Date created: 03/19/2019
Last updated: 03/19/2019