ISO 13528 PLOT

ISO 13528 PLOT

Graphics Command

Generate a z-score versus lab average plot as given in the ISO 13528 standard.

One scenario for proficiency testing described in the ISO 13528 standard is for the case where there are multiple rounds of testing. That is, we have the following data:

Y	-	a variable containing either the response data in the orignal units or the laboratory averages
Z	-	a variable containing the response data in z-score units
ROUNDID	-	a variable containing the round-id
LABID	-	a variable containing the lab-id
LAB2	-	a variable containing a list of one or more laboratories for which the plot is generated

Although the proficiency test may have multiple materials, this plot is restricted to a single material.

Then for the labs identified in LAB2, the plot is formed as:

Vertical Axis:	zi = the z-score for round i for the specified lab.
Horizontal Axis:	\( \bar{y}_{i} \) = the average value over all laboratories (in the original units).

Although this plot is most typically generated for a single laboratory, it can also be used to plot the z-scores for multiple laboratories.

In addition, a line is fit to the plot points. The primary question for the fitted line is whether there is any trend (i.e., is the slope parameter for the fitted line statistically significant). A separate line is fit for each laboratory specified by the &;lt;LAB2> variable.

What is used for the Y variable is dependent on what data is available to you. If you have the original raw data (i.e., before z-scores were computed), then this is typically what you would use (i.e., let Dataplot compute the laboratory averages). However, in some cases you may not have the original data. There are two cases:

1. Even if you do not have the response data in the original units, you may have the laboratory averages in the original units. If Y contains the laboratory averages, it should be equal to the number of distinct values in the ROUNDID variable.

2. If you do not have either the original data or the laboratory averages in the original units, then just use the z-scores for the Y variable. If Y contains either the original response data or the z-scores, then the Y variable should be the same length as the Z variable. If the z-scores are used for the Y variable, then the horizontal axis is in z-score units rather than the original units of the data.

See the Note section below for details on how to specify which case is being used.

You can optionally specify a material-id variable. This is essentially a highlighting variable. That is, different materials can be drawn with different plot characters (this is demonstrated in the Program example below).

ISO 13528 PLOT <y> <z> <roundid> <labid> <lab2>
                        <SUBSET/EXCEPT/FOR qualification>
where <y> is the response variable in the original units;
            <z> is the z-scores of the response variable;
            <roundid> is a variable that specifies the round-id;
            <labid> is a variable that specifies the lab-id;
            <lab2> is a variable that specifies the laboratories for which the plot will be generated;
and where the <SUBSET/EXCEPT/FOR qualification> is optional.

ISO 13528 PLOT <y> <z> <roundid> <labid> <matid> <lab2>
                        <SUBSET/EXCEPT/FOR qualification>
where <y> is the response variable in the original units;
            <z> is the z-scores of the response variable;
            <roundid> is a variable that specifies the round-id;
            <labid> is a variable that specifies the lab-id;
            <matid> is a variable that specifies the mat-id;
            <lab2> is a variable that specifies the laboratories for which the plot will be generated;
and where the <SUBSET/EXCEPT/FOR qualification> is optional.

LET LAB2 = DATA 3
ISO 13528 PLOT Y Z ROUNDID LABID LAB2
ISO 13528 PLOT Y Z ROUNDID LABID LAB2 SUBSET MATID = 2

The coefficients, standard deviations of the coefficients, and the t-values for the fitted lines are written to the file "dpst1f.dat". See the Program example below to see how these values can be read from the file to annotate the plot.

If the <LAB2> variable identifies more than one laboratory, the plot points for each laboratory are drawn as separate curves. The appearance of the plot can be controlled by approriate settings for the LINE and CHARACTER commands and their associated attribute setting commands. For example,
LET LAB2 = DATA 3 5
LINE BLANK SOLID BLANK SOLID BLANK SOLID
CHARACTER 3 BLANK 5 BLANK
ISO 13528 PLOT Y Z ROUNDID LABID LAB2


Note that these settings come in pairs. The second setting in the pair is for the fitted line. This is demonstrated in the program example below.

If you want the Y variable to contain the laboratory averages rather than the original data or z-scores, enter the command
SET ISO 13528 PLOT LAB AVERAGES

If you want the Y variable to contain either the original data or the z-scores, enter the command

SET ISO 13528 PLOT RESPONSE

If Dataplot computes the laboratory averages, it will compute the mean by default. However, you can alternatively specify the median or the H15 location statistic with the commands
SET ISO 13528 PLOT STATISTIC MEDIAN
SET ISO 13528 PLOT STATISTIC H15


To reset the default of using the mean, enter

The ISO 13528 standard defines a number of methods for computing the z-scores (enter HELP ISO 13528 ZSCORE, HELP ISO 13528 ZPRIME SCORE, and HELP ISO 13528 ZETA SCORE for details). For this reason, the ISO 13528 PLOT command does not automatically compute the z-scores from the original response data.

None

None

ISO 13528 ZSCORE PLOT	=	Generate an ISO 13528 z-score or j-score plot.
ISO 13528 ZSCORE	=	Compute z-scores as defined in the ISO 13528 standard.
ISO 13528 ZPRIME SCORE	=	Compute z-prime scores as defined in the ISO 13528 standard.
ISO 13528 ZETA SCORE	=	Compute zeta scores as defined in the ISO 13528 standard.
CHARACTER	=	Sets the type for plot characters.
LINE	=	Sets the type for plot lines.

ISO 13528 (2005), "Statistical Methods for use in proficiency testing by interlaboratory comparisons," First Edition, 2005-09-01, pp. 56-57.

Proficiency Testing

2012/2

. Step 1: Read the data (note that this sample data set only
.         has z-scores)
.
dimension 40 columns
skip 25
read turner.dat labid z year quarter matid matave
let roundid = year
skip 0
.
. Step 2: Some plot control settings
.
label case asis
y1label Z-Score
x1label Laboratory Averages
tic mark offset units screen
tic mark offset 3 3
.
case asis
title case asis
title offset 2
title ISO 13528 Plot
.
line blank solid
character circle blank
character hw 1 0.75
character fill on
.
. Step 3: Generate the plot for lab 3
.
set iso 13528 plot response
let lab2 = data 3
iso 13528 plot z z roundid labid lab2
.
. Step 4: Annotate the plot with the fit parameters
.
skip 1
read parameter dpst1f.dat ppa0 ppa1 ppa0sd ppa1sd a0tval a1tval
skip 0
let ppa0 = round(ppa0,2)
let ppa1 = round(ppa1,2)
let ppa0sd = round(ppa0sd,2)
let ppa1sd = round(ppa1sd,2)
let a0tval = round(a0tval,2)
let a1tval = round(a1tval,2)
just center
move 50 6
text Intercept = ^ppa0, SD = ^ppa0sd, t-Value = ^a0tval
move 50 3
text Slope = ^ppa1, SD = ^ppa1sd, t-Value = ^a1tval
    



.
. Step 5: Use the material-id
.
line blank all
character 1 2 3 4 5 6 7 8 9 10
character fill off
character hw
iso 13528 plot z z roundid labid matid lab2