MEDIAN SCORE

MEDIAN SCORE (LET)

Let Subcommand

Compute the median scores of a variable.

The median scores are defined as
\( \begin{array} s(R_{j}) & = 1 \hspace{0.2in} \mbox{if} R_j > \frac{n+1}{2} \\ & = 0 \hspace{0.2in} \mbox{if} R_j \le \frac{n+1}{2} \\ \end{array} \)

where \( R_{j} \) is the rank of the j-th observation and n is the number of observations. That is, ranks that are greater than the median of the ranks are given a value of 1 and ranks that are less than or equal to the median rank are given a value of 0.

Median scores are typically used in nonparametric statistics. For example, using median scores in the two sample linear rank test generates the two sample median test and using median scores in a one-way ANOVA generates the Brown-Mood test.

LET <s> = MEDIAN SCORE <y>
                  <SUBSET/EXCEPT/FOR qualification>
where <y> is the response variable;
            <s> is a variable where the computed median scores are saved;
and where the <SUBSET/EXCEPT/FOR qualification> is optional.

LET MEDSCORE = MEDIAN SCORE Y

Ties are assigned an average rank. For example, if the 2nd and 3rd highest values are equal, each is assigned a rank of 2.5.

None

None

MEDIAN TEST	=	Perform a median test.
KLOTZ TEST	=	Perform a Klotz test for equal variances.
ANOVA	=	Perform a fixed effects analysis of variance.
MOOD SCORES	=	Generate Mood scores.
KLOTZ SCORES	=	Generate Klotz scores.
VAN DER WAERDEN SCORES	=	Generate Van Der Waerden scores.
SAVAGE SCORES	=	Generate Savage scores.
CONOVER SCORES	=	Generate Conover scores.
ANSARI BRADLEY SCORES	=	Generate Ansari Bradley scores.
PLACEMENT SCORES	=	Generate placement scores.
RANK	=	Generate the ranks of a variable.

Nonparametric statistics

2023/06

 
. Step 1:   Define the data
.
let y1 = data 16.55 15.36 15.94 16.43 16.01
let y2 = data 16.05 15.98 16.10 15.88 15.91
let n1 = size y1
let n2 = size y2
let n = n1 + n2
.
. Step 2:   Combine into single array
.
let y tag = stack y1 y2
if n1 <= n2
   let tag = tag - 1
   let n1t = n1
else
   let tag = 0 subset tag = 2
   let n1t = n2
end of if
.
. Step 3:   Compute the median scores
.
let ymedian = median scores y
.
. Step 4:   Two-sample median test
.
.            Two-Sample Linear Rank Test
.
let temp = tag*ymedian
let s = sum temp
.
let aval = sum ymedian
let smean = (n1t/n)*aval
let meanrank = mean ymedian
let temp = (ymedian - meanrank)**2
let aval = sum temp
let svar = ((n1*n2)/(n*(n-1)))*aval
let statval = (s - smean)/sqrt(svar)
let statval = round(statval,3)
let cv = norppf(0.975)
let upplim = round(cv,2)
let lowlim = -upplim
feedback off
print "Two Sample Linear Rank Sum Test Based on Median Scores"
print "H0: Medians are Equal"
print "Ha: Medians are Not Equal"
print "alpha: 0.05"
print "Test Statistic: ^statval"
print "Lower Critical Value: ^lowlim"
print "Upper Critical Value: ^upplim"
if statval < cv
   print "Conclusion: Accept H0"
else
   print "Conclusion: Reject H0"
end of if
    

The following output is generated

 
Two Sample Linear Rank Sum Test Based on Median Scores
H0: Medians are Equal
Ha: Medians are Not Equal
alpha: 0.05
Test Statistic: -0.6
Lower Critical Value: -1.96
Upper Critical Value: 1.96
Conclusion: Accept H0