CARRIAGE RETURN GAP

CARRIAGE RETURN GAP (SET)

Set Subcommand

For multiline text written on a plot (TEXT, LEGEND, TITLE, LABEL, TIC MARK LABEL CONTENT commands), specify a "fudge" factor to add to the distance between the lines.

In Dataplot you can specify multiple lines by using the "CR()" sequence. For example, to create a multiline title, do something like
TITLE This is Line Onecr()and This is Line Two

The gap between the first line and the second line is based on the requested character size. In some cases, you may want to increase the distance between the two lines. The SET CARRIAGE RETURN GAP command can be used to add a fudge factor to the default distance. This fudge factor is specified in 0 to 100 screen units.

Multiline text is most commonly used with the TITLE, TEXT, and TIC MARK LABEL commands. When alphabetic tic mark labels are used, multiline labels can be a useful way to avoid overlap while still retaining meaningful labels. The SET CARRIAGE RETURN GAP can be particularly useful when using the MULTIPLOT command.

SET CARRIAGE RETURN GAP <value>
where <value> is a number or parameter in the range -5 to 5.

Typical values are in the range 0 to 1. Although negative values are allowed (these actually decrease the default distance between lines), they are rarely used.

SET CARRIAGE RETURN GAP 0
SET CARRIAGE RETURN GAP 0.1
SET CARRIAGE RETURN GAP 0.5

The default value is 0.1.

None

TEXT	=	Write a text string immediately.
TITLE	=	Specify the title for a plot.
LEGEND	=	Specify text to be generated on subsequent plots.
LABEL	=	Specify an x- or y-axis label for a plot.
TIC MARK LABEL CONTENT	=	Specify the content for alphabetic tic mark labels.

Annotating Plots

2019/02

 
. Step 1:   Read the data and generate a fit
.
skip 25
read berger1.dat y x batch
skip 0
.
fit y x
let a0 = round(a0,2)
let a1 = round(a1,2)
let cc = corr y x
let cc = round(cc,2)
.
. Step 2:   Generate the plot
.
title offset 2
title case asis
label case asis
legend case asis
character case asis
case asis
.
title Fit for Alaska Pipeline Data (File: BERGER1.DAT)
x1label Lab Defect Size
y1label Field Defect Size
.
line blank
character X
.
plot y x
.
. Step 3:   Annotate the plot
.
set tab horizontal position 1 25
set tab horizontal position 2 35
set tab justification 1 right
set tab justification 2 left
set tab size  1 3
.
justification left
move 17 85
text a0:tab()^a0 tab()Intercept
.
move 17 82
text a1:tab()^a1 tab()Slope
.
set carriage return gap 0.2
set tab color 1 red
set tab color 2 blue
move 17 79
text Corr:tab()^cc tab()Linearcr()Correlation
    

 
skip 25
read nor.dat      y1
read exp.dat      y2
read weibbury.dat y3
read lgn.dat      y4
read gamma.dat    y5
read frechet.dat  y6
let y x = stack y1 y2 y3 y4 y5 y6
skip 0
.
case asis
label case asis
title case asis
title offset 2
multiplot corner coordinates 2 2 98 98
multiplot scale factor 2
set carriage return gap 0.5
.
. Step 2:   Plot normal a-d statistic
.
multiplot 2 2
y1label Anderson-Darling Statistic
x3label Datasets
xlimits 1 6
major xtic mark number 6
minor xtic mark number 0
x1tic mark offset 0.5 0.5
x1tic mark label format alpha
x1tic mark label content NOR.DAT sp()cr()sp()cr()EXP.DAT WEIBBURY.DAT ...
      sp()cr()sp()cr()LGN.DAT GAMMA.DAT sp()cr()sp()cr()FRECHET.DAT
x1tic mark label size 1.2
y1label displacement 12
ylimits 0 1
character X
line blank
.
title Normal AD
normal anderson darling plot y x
.
ylimits
y1label Location
title Normal AD Location
normal anderson darling location plot y x
.
y1label Scale
title Normal AD Scale
normal anderson darling scale plot y x
.
end of multiplot
.
justification center
move 50 3
text Datasets